Lister les mises à jour Windows installées

'2014 octobre 28 version : add name server on file generated

Dim ActualDay
Dim MyDay
Dim MyMonth
Dim objFSO
Dim objTextFile
Dim CheminFichier
Dim CheminScriptActuel
Dim WSHShell
Dim vCOMPUTERNAME

'Déclaration des constantes
Const ForReading = 1
Const ForWritting = 2
Const ForAppending = 8

'Determine actual date
MyDay = Day(Now)
MyMonth = Month(Now)

If Len(MyDay) = 1 Then
	MyDay = "0" & MyDay
End If

If Len(MyMonth) = 1 Then
	MyMonth = "0" & MyMonth
End If
ActualDay = Year(Now) & "-" & MyMonth & "-" & MyDay

Set WSHShell = CreateObject("WScript.Shell") 
vCOMPUTERNAME = WSHShell.ExpandEnvironmentStrings("%COMPUTERNAME%")

CheminScriptActuel = Left(wscript.scriptfullname,Len(wscript.scriptfullname)-Len(wscript.scriptname)-1)
CheminFichier = CheminScriptActuel & "\" & vCOMPUTERNAME & "_ListUpdatesInstalled_" & ActualDay & ".txt" 'Déclaration du chemin et du nom du fichier


Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(CheminFichier, ForWritting, True)

Set objSession = CreateObject("Microsoft.Update.Session")
Set objSearcher = objSession.CreateUpdateSearcher
Set objResults = objSearcher.Search("Type='Software'")
Set colUpdates = objResults.Updates

For i = 0 to colUpdates.Count - 1
	If colUpdates.Item(i).IsInstalled <> 0 Then
		objTextFile.WriteLine(colUpdates.Item(i).Title)
	End If
Next

objTextFile.WriteLine("-----------------------------")


objTextFile.Close 'Fermeture du fichier

Set objTextFile = Nothing
Set objFSO = Nothing